home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tele-Info Vol. 2
/
Tele-Info Vol. 2 (1997)(Tele-Info Verlag)(DE)[!].iso
/
Installieren
< prev
next >
Wrap
Text File
|
1997-03-17
|
7KB
|
232 lines
; ---------------------------------------------------------------------
;
; $VER: TeleInfo Installer Script 2.0 (10.03.97)
;
; Script to install TeleInfo (german version)
;
; ---------------------------------------------------------------------
; ---------------------------------------------------------------------
;
; STRINGS (German)
;
; ---------------------------------------------------------------------
(set #SourceDir "TeleInfo2CD:")
(set #SourceDataDir (tackon #SourceDir "Data"))
(set #TeleInfoPattern "TeleInfo#?")
(set #ExtraIndex "Z1.ind")
(set #TeleInfoDial "Dial.rexx")
(set #AskDestDir
(cat "Bitte wählen Sie das Verzeichnis, in dem TeleInfo "
"installiert werden soll. "
"Es wird automatisch ein neues Verzeichnis 'TeleInfo' "
"für das Programm und die Daten angelegt." )
)
(set #AskDestDirHelp
(cat "Für die Installation werden auf dem Ziellaufwerk "
"je nach Installation 1 bis 33 MByte "
"freier Speicherplatz benötigt.\n\n"
"Das Installationsprogramm erstellt in dem ausgewählten "
"Pfad ein neues Verzeichnis 'TeleInfo'. Alle Dateien "
"werden in dieses Verzeichnis kopiert.\n\n"
"Sollten Sie bereits Besitzer einer alten Version von TeleInfo "
"sein, so haben Sie die Möglichkeit, Ihre alten Daten ersetzen "
"zu lassen. Wählen Sie dazu das Verzeichnis aus, in dem sich "
"das alte TeleInfo-Verzeichnis befindent (d.h. das alte TeleInfo-"
"Verzeichnis muß in der Verzeichnisliste zu sehen sein - "
"wechseln Sie ***nicht*** in dieses Verzeichnis)\n\n"
"Sie können nach der Installation dem Verzeichnis natürlich "
"einen anderen Namen geben." )
)
(set #WhichPartsPrompt
(cat "Bitte wählen Sie aus, welche der folgenden "
"Installationsvarianten Sie installieren möchten:" )
)
(set #WhichPartsHelp
(cat "Wählen Sie die Variante, wie Sie TeleInfo installieren möchten:\n\n"
"Nur Link: Es wird nur ein Icon erzeugt, das Programm und alle Daten "
"bleiben auf der CD-Rom. Sehr langsam!!! (siehe auch 'Minimal')\n\n"
"Minimal: Hierbei werden alle Dateien, auch die Indexdateien, direkt "
"vom CD-Laufwerk gelesen. Dies führt zu sehr langen Wartezeiten "
"und ist nur zu empfehlen, wenn Sie über sehr wenig Festplattenspeicher "
"verfügen!\n\n"
"Standard: Bei dieser Einstellung werden die wichtigsten Indexdateien "
"auf Ihre Festplatte kopiert. Diese belegen 26 MByte. Dies ist die "
"empfohlene Einstellung für Systeme mit kleiner Festplatte.\n\n"
"Optimal: Es werden alle Indexdateien auf Ihre Festplatte kopiert. "
"Diese Option belegt gegenüber 'Standard' weitere 7 MByte - ingesamt "
"also 33 MByte. Sollten Sie über ausreichend Festplattenkapazität "
"verfügen, so sollten Sie diese Option wählen." )
)
(set #WhichPart0 "Nur Link (1 KByte, nicht empfohlen!)")
(set #WhichPart1 "Minimal (0,2 MByte, nicht empfohlen!)")
(set #WhichPart2 "Standard (26 MByte)")
(set #WhichPart3 "Optimal (33 MByte)")
(set #VorwahlPrompt
(cat "Bitte geben Sie Ihre Vorwahl ein. Diese wird für die "
"automatische Wahl per <Bearbeiten-Wählen> benötigt."
)
)
(set #VorwahlHelp
(cat "TeleInfo bietet die Möglichkeit, eine gefundene Telefonnummer "
"automatisch wählen zu lassen (per ARexx-Script Dial.rexx).\n"
"Dieses wird vom Installer so konfiguriert, daß bei Telefonnummern "
"in Ihrem Vorwahlbereich die Vorwahl automatisch ausgelassen wird.\n"
"Dazu müssen Sie die Ihre Vorwahl (etwa 030) eingeben."
)
)
; ---------------------------------------------------------------------
;
; INSTALLATION SCRIPT - BEGIN
;
; ---------------------------------------------------------------------
;*** get OS version
(set #osversion 3)
(if (< (/ (getversion) 65536) 39) (set #osversion 2) )
(if (< (/ (getversion) 65536) 36) (set #osversion 1) )
;**** ask user which parts to copy (average & expert )
(complete 3)
(set whichparts 2) ; default: Standard
(if (> @user-level 0)
(
(set whichparts
(askchoice
(prompt #WhichPartsPrompt)
(help #WhichPartsHelp)
(choices #WhichPart0 #WhichPart1 #WhichPart2 #WhichPart3)
(default whichparts)
)
)
)
) ; if (userlevel)
;**** ask user where to put TeleInfo
(set DestDir
(askdir
(prompt #AskDestDir )
(help #AskDestDirHelp )
(default "Work:")
)
)
; *** ask for Vorwahl (always, i.e. minimum user level 1)
(set userlevel @user-level) (if (= 0 @user-level) (user 1))
(set Vorwahl
(askstring
(prompt #VorwahlPrompt)
(help #VorwahlHelp)
(default "030")
)
)
(if (= 0 userlevel) (user 0))
;****
(set RealDest (tackon DestDir "TeleInfo"))
(set RealDestData (tackon RealDest "Data"))
(if (= (exists RealDest) 0)
(makedir RealDest (infos))
)
(if (> whichparts 1)
(
(if (= (exists RealDestData) 0)
(makedir RealDestData)
)
)
)
; *** copy main programm
(complete 5)
(if (= whichparts 0)
(
(copyfiles
(source (tackon #SourceDir "Extra"))
(dest RealDest)
(choices "TeleInfo.info")
)
)
(
(copyfiles
(source #SourceDir)
(dest RealDest)
(pattern #TeleInfoPattern)
(infos)
)
)
)
; *** copy main index files
(complete 20)
(if (= whichparts 1)
(
(tooltype
(dest (tackon RealDest "TeleInfo"))
(settooltype "INDEX" "TeleInfo2CD:Data")
)
)
)
(if (> whichparts 1)
(
(copyfiles
(source #SourceDataDir)
(dest RealDestData)
(all)
)
)
)
(if (= whichparts 2) ; falls "Standard" gewählt, "z1.ind" (Optimal) entfernen!
( ; ist vielleicht noch von einer alten Version übrig
(delete (tackon RealDestData "z1.ind")
(optional "force")
)
)
)
; *** copy additional index file(s)
(complete 85)
(if (> whichparts 2)
(
(copyfiles
(source #SourceDir)
(dest RealDestData)
(choices #ExtraIndex)
)
)
)
; *** assemble and create Dial.rexx
(complete 95)
(textfile
(dest (tackon RealDest #TeleInfoDial))
(include (tackon #SourceDir "Extra/Dial1.txt"))
(append Vorwahl)
(include (tackon #SourceDir "Extra/Dial2.txt"))
)
; *** assemble and create ENVARC:TeleInfo.path
;(complete 98)
;(textfile
; (dest "ENVARC:TeleInfo.path")
; (append RealDest)
;)
(set @default-dest RealDest)
(complete 100)
; ---------------------------------------------------------------------
;
; INSTALLATION SCRIPT - END
;
; ---------------------------------------------------------------------